QueryDsl의 설정방법— 스프링 부트 2.7버전 이전 버전기준

implementation 'com.querydsl:querydsl-jpa:5.0.0'

annotationProcessor(

      "javax.persistence:javax.persistence-api",

      "javax.annotation:javax.annotation-api",

      "com.querydsl:querydsl-apt:5.0.0:jpa")

위 코드를 build.gradle에 추가하고, 최상위 폴더 아래에 있는 build.generated.sources.annotationProcesser.java.main 폴더를 잘 확인해보면 엔티티를 기반으로 한 Q~~~~ 클래스들이 생성되어있을 것이다.

하지만, 위치가 마음에 들지 않는 경우에는 지정할 수 있는 방법이 있다.

plugins {
	id 'java'
	id 'org.springframework.boot' version '2.7.8'
	id 'io.spring.dependency-management' version '1.0.15.RELEASE'
//queryDsl 설정시 필요한 플러그인
	id 'com.ewerk.gradle.plugins.querydsl' version '1.0.10'
}

group = 'org.cvcvcx'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
//queryDsl 설정시 필요한 설정
	querydsl.extendsFrom compileClasspath
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	compileOnly 'org.projectlombok:lombok'
	developmentOnly 'org.springframework.boot:spring-boot-devtools'
	runtimeOnly 'org.mariadb.jdbc:mariadb-java-client'
	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'

	//querydsl관련
	// https://mvnrepository.com/artifact/com.querydsl/querydsl-jpa
	implementation 'com.querydsl:querydsl-jpa:5.0.0'
	annotationProcessor "com.querydsl:querydsl-apt:5.0.0"

}

//compileJava 실행시 이 위치에 코드가 생성된다.
def querydslDir = "$buildDir/generated/querydsl"

querydsl {
	jpa = true
//코드 위치를 지정해주는 변수명
	querydslSourcesDir = querydslDir
}

sourceSets {
	main.java.srcDir querydslDir
}


compileQuerydsl {
	options.annotationProcessorPath = configurations.querydsl
}


tasks.named('test') {
	useJUnitPlatform()
}

Uploaded by N2T